home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Diamond Collection
/
The Diamond Collection (Software Vault)(Digital Impact).ISO
/
cdr37
/
rreq11b.zip
/
REGREQ.PPS
< prev
next >
Wrap
Text File
|
1995-03-24
|
6KB
|
185 lines
;------------------------------------------------------------------------
; REGREQ.PPE v1.0
; Copyright 1995 - Herbert Bushong
;------------------------------------------------------------------------
; A New user log-in PPE for to allow a new user to
; Download an any of a list of files and optionally logging them off.
; This PPE is used in a security specific display file
;
; Uses a config file and a list file to supply necessary information
*$USEFUNCS
*$INCLUDE:d:\pcb\ppl\libs\miscfn.lib
STRING ListFile, CfgFile, RRIntroFile, RRDLFile(1,1),DLSel(1), TempIn
STRING DLCmd, DLProt, NumFiles, YNLogoff
STRING MsgTemp, MsgPriv, MsgFrom, MsgTo, MsgConf, MsgSubject
STRING RRName, RRStreet1, RRStreet2, RRCity, RRState, RRZip, RRCountry
INTEGER fh1, i, iTempIn
BOOLEAN Files2DL
BEGIN
ListFile=PPEPATH()+PPENAME()+".LST"
CfgFile=PPEPATH()+PPENAME()+".CFG"
MsgTemp=PPEPATH()+"RRTMPMSG.$$$"
MsgFrom="SYSTEM DAEMON"
MsgSubject=PPEName()+": notice"
DLCmd="D"
DLProt="Z"
Files2DL=FALSE
;READ CONFIG FILE
fh1=FNEXT()
fopen fh1, CfgFile, O_RD,S_DN
if (FERR(fh1)) THEN
LOG FALSE, "Error opening "+CfgFile
PRINTLN "An Error Occured. Please notify sysop...."
GOTO finished
ENDIF
RRIntroFile=GetCfgLine(fh1)
YNLogoff=GetCfgLine(fh1)
MsgTo=GetCfgLine(fh1)
IF (MsgTo="") Let MsgTo="SYSOP"
MsgConf=GetCfgLine(fh1)
If (MsgConf="") LET MsgConf="0"
MsgPriv = UPPER(GetCfgLine(fh1))
If ((MsgPriv<>"N")&&(MsgPriv<>"R")) Let MsgPriv="R"
FCLOSE fh1
fh1=FNEXT()
fopen fh1, CfgFile, O_RD,S_DN
if (FERR(fh1)) THEN
LOG FALSE, "Error opening "+ListFile
PRINTLN "An Error Occured. Please notify sysop...."
GOTO finished
ENDIF
NumFiles=s2i(GetCfgLine(fh1),"10") ;Get # of File entries
Redim RRDLFile, NumFiles, 1
Redim DLSel, NumFiles
for i=1 to NumFiles
RRDLFile (i,1)=GetCfgLine(fh1) ;Get File Description
RRDLFile (i,0)=GetCfgLine(fh1) ;Get File Name
DLSel(i)=" "
NEXT i
FCLOSE fh1
;DISPLAY INTRO FILE, LIST FILE DESCRIPIONS and ASK which to DL
CLS
DISPFILE RRIntroFile, GRAPH+LANG
NEWLINE
WAIT
iTempIn=NumFiles+1
;LIST FILE DESCRIPIONS and ASK which to DL
:StartList
CLS
PRINTLN "@X0AThe following files are available for Downloading: @X07"
NEWLINE
For I=1 to NumFiles
PRINTLN "@X0E"+RIGHT(STRING(i),3)+")@X0C"+DLSel(i)+"@X0F"+RRDLFile(i,0)+"@X07"
NEXT i
PRINTLN "@X0E"+RIGHT(STRING(NumFiles+1),3)+") @X0BDownload Selected Files@X07"
PRINTLN "@X0E 0) @X0BDo Not download anything now@X07"
Newline
iTempIn=0
TempIn=""
INPUTSTR "Enter Number to toggle for Downloading or action to take",TempIn,@X0E,3,"1234567890",LFAFTER+FIELDLEN
IF (TempIN="") GOTO StartList
iTempIn=s2i(TempIn,"10")
IF (iTempIn>(NumFiles+1)) GOTO StartList
IF (iTempIn=0) Goto AskMail
IF (iTempIn=(NumFiles+1)) Goto StartDL
SELECT CASE (DLSel(iTempIn))
CASE " "
DLSel(iTempIn)="*"
CASE "*"
DLSel(iTempIn)=" "
DEFAULT
DLSel(iTempIn)="*"
ENDSELECT
GOTO StartList
NEWLINE
:StartDL
PrintLn "@X09Flagging Chosen Files...@X07"
For I=1 to NumFiles
IF (DLSel(i)="*") THEN
Files2DL=TRUE
FLAG RRDLFile(i,1)
ENDIF
NEXT I
IF (!(Files2DL)) GOTO AskMail
CLS
PRINTLN "@X0ABefore downloading, please provide the following information@X07"
InputStr "Please provide your Real Name",RRName,@X0A,45,MASK_ALPHA(),LFAFTER+FIELDLEN
NewLine
PrintLN "@X0BChoose a Transfer Protocol"
InputStr "(X)-modem, (Y)-Modem, or (Z)-modem",DLProt,@X0B,1,"xzyXYZ",LFAFTER+FIELDLEN
DLCmd=DLCmd+";"+DLProt
KBDSTUFF "Y"
COMMAND FALSE,DLCmd
KBDFLUSH
fh1=FNEXT()
FCREATE fh1,MsgTemp,O_WR,S_DB
FPUTLN fh1, RRName
FPUTLN fh1, "has downloaded the Following files:"
For I=1 to NumFiles
IF (DLSel(i)="*") THEN
FPUT fh1, RRDLFile(i,0)+" - "
FPUTLN fh1, RRDLFile(i,1)
ENDIF
NEXT I
FCLOSE fh1
GOTO SendMessage
:AskMail
TempIn="Y"
PRINTLN "@X0AYou have decided not to download the files"
INPUTYN "Would you like to an application Mailed to you",TempIn,@X0A
TempIn=UPPER(TempIn)
NEWLINE
IF (TempIn=NoChar()) Goto Finished
CLS
PRINTLN "@X0APlease Provide the Following Information@X07"
Newlines 2
TempIn=""
PROMPTSTR 259, TempIn, 25,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
RRName=TempIn
TempIn=""
PROMPTSTR 260, TempIn, 25,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
RRName=RRName+TempIn
DISPTEXT 698, NEWLINE
PROMPTSTR 699, RRStreet1, 50,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 700, RRStreet2, 50,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 701, RRCity, 25,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 702, RRState,10,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 703, RRZip, 10,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 704, RRCountry, 15,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
fh1=FNEXT()
FCREATE fh1,MsgTemp,O_WR,S_DB
FPUTLN fh1, RRName
FPUTLN fh1, "has requested you mail information to him/her."
FPUTLN fh1, "The following address info was provided:"
FPUTLN fh1, ""
FPUTLN fh1, RRName
FPUTLN fh1, RRStreet1
if (TRIM(RRStreet2," ")<>"") FPUTLN fh1, RRStreet2
FPUTLN fh1, TRIM(RRCity," ")+", "+RRState+" "+RRZip
FPUTLN fh1, RRCountry
FCLOSE fh1
:SendMessage
NEWLINES 2
PRINTLN "@X0DSending Message to Sysop@X07"
MESSAGE S2I(MsgConf,"10"), MsgTo, MsgFrom, MsgSubject, MsgPriv, 0, FALSE, FALSE, MsgTemp
CLS
PRINTLN "@X0AThank you...@X07"
:Finished
IF (YNLogoff="Y") THEN
PRINTLN "@X0CLogging off... @X07"
BYE
ENDIF
END